In my previous post I wrote about whyI use object oriented Lotusscript. Let’s look at how it can be used in a real-life application.
Background
At my work I developed a system to handle insurance claims. Each claim can have one or more claimants, people or parties that have either BI (bodily injury) or PD (property damage) claims related to an accident. Each claimant get a reserve setup, an amount of money the adjuster think it will cost to settle the claimant. There are two reserves for each claimant, one for loss payments and one for expense payments. The latter can be payments for police reports, field adjusters, lawyer fees, etc while loss payments are the actual damages (payments to body shops, medical payments, etc).
When payments are made, the reserve amounts are reduced, until reaching zero. No more payments can be done then until the reserve is increased. Each adjuster have a limit to how large reserve he or she can set, higher reserve must be approved by a manager.
When payments are made, the reserve amounts are reduced, until reaching zero. No more payments can be done then until the reserve is increased. Each adjuster have a limit to how large reserve he or she can set, higher reserve must be approved by a manager.
Data storage
When the claim system was first put in place, all reserves and payments werestored in the Notes database. They were then (manually) transferred into a backend system built in Visual FoxPro. But after a few years, a COM object (dsClaimLink) was developed and the Notes database is now sending all financial transaction into the backend, and retrieving financial information the same way when needed. Claim information is stored in the Notes database, as is claimant information. Some claimant information. a sub-set of the data stored in Notes,is sent to the backend as well.
Original design
Initially I built a large number of functions and subroutines, organized in different script libraries based on functionality.This actually worked really good, and the code was fairly easy to maintain, modify and expand. When the financial transactions were moved to the backend, I just had to modify the function GetAvailableAmount() to call the backend instead of looking up the amount in the Notes database. But it was still not very flexible, andI had some code that was duplicated in many places (most of it related to calling the COM object). So about two years ago, I started refactoring my code, both to make it faster and easier to maintain, by using object oriented Lotuscript.
Example
Beloware examples of the code in the script library Class.ClaimData class. This is not my exact production code, I have removed a number of lines to make the example more clear.
The ClaimData class (described in next posting)contains an array of claimants, each of those an object. Each claimant object in turn contains an object containing the different amounts (loss reserve/loss payments, expense reserve/expense payments, recovery amount, etc).
First, let’s look at the AmountData object.
Class AmountData
Public lr As Currency ' Loss Reserve
Public er As Currency ' Expense Reserve
Public lp As Currency ' Loss Payments
Public ep As Currency ' Expense Payments
Public slp As Currency ' Supplemental Loss Payments
Public sep As Currency ' Supplemental Expense Payments
Public rec As Currency ' Recovery amount
Public lossavail As Currency
Public expavail As Currency
Public Sub New()
rec = 0
slp = 0
sep = 0
lr = 0
er = 0
lp = 0
ep = 0
lossavail = -1
expavail = -1
End Sub
Public Sub Load(claimnumber As String, claimant As Integer)
Dim success As Integer
Dim servaddress As String
Dim xmldata As String
Dim claimlink As ClaimLink ' Object to connect to backend
Set ClaimLink = New ClaimLink() ' Create object/class
If claimant = 0 Then ' Get total amounts for all claimants
success = claimlink.GetClaimStatus(claimnumber, Today())
Else ' Get amounts for selected claimant
success = claimlink.GetAmountsByClaimant(claimnumber, claimant, Today())
End If
If success = True Then ' Data returned successfully
xmldata = claimlink.GetDataXML()
rec = Cstr(Ccur(XMLGetValue(xmldata,"recovery")))
slp = Cstr(0-Ccur(XMLGetValue(xmldata,"losssup")))
sep = Cstr(0-Ccur(XMLGetValue(xmldata,"expsup")))
If claimant = 0 Then ' All claimants
lr = Cstr(Ccur(XMLGetValue(xmldata,"lossorig")) + Ccur(XMLGetValue(xmldata,"losschg")))
er = Cstr(Ccur(XMLGetValue(xmldata,"exporig")) + Ccur(XMLGetValue(xmldata,"expchg")))
Else ' Specified claimant
lr = Cstr(Ccur(XMLGetValue(xmldata,"lossres")) - Ccur(slp) + Ccur(rec))
er = Cstr(Ccur(XMLGetValue(xmldata,"expres")) - Ccur(sep))
End If
lp = Cstr(0-Ccur(XMLGetValue(xmldata,"losspaid")) - Ccur(slp))
ep = Cstr(0-Ccur(XMLGetValue(xmldata,"exppaid")) - Ccur(sep))
lossavail = Ccur(lr) - Ccur(lp)
expavail = Ccur(er) - Ccur(ep)
End If
End Sub
End Class
As you perhaps noticed, I encapsulated the dsClaimLink functionality in an obect as well. I am also using my own XML parsing functions, as the system was built in Notes R5.
When the object is created, I do not lead the amounts directly. I just set all amounts to 0, with two exceptions. The available amounts are set to -1 (a value they will normally never have). This indicate that data have not been loaded, or that the attempt to load data failed.
The Load() method of the class call the COM object (dsClaimLink) withone of two functions depending on how the method is called. This let meuse the AmountData object notjust for amounts for a specified claimant, but also for claim level amounts,totals for all claimants.
Next we have a small object used to decide if a claimant is open or closed.The expense and loss parts of a claimant can be closed and (re-)openedindividually. If either is open, the claimant is open, if both are closed, the claimant is considered closed. That is why I built this object, to get an easy status indication in the claimant object.
Class ClaimantStatusData
Public loss As String
Public expense As String
Public claimant As String
Public Sub new(doc As NotesDocument)
If Lcase(doc.LossClosed(0)) = "yes" Then
Me.loss = "closed"
Else
Me.loss = "open"
End If
If Lcase(doc.ExpensesClosed(0)) = "yes" Then
Me.expense = "closed"
Else
Me.expense = "open"
End If
If Me.expense = "closed" Then
If Me.loss = "closed" Then
Me.claimant = "closed"
Else
Me.claimant = "open"
End If
Else
Me.claimant = "open"
End If
End Sub
End Class
Nothing very complicated, but a big help later on.
The final class I will show today is the actual ClaimantData class. As you can see,I am using the classed I described earlier here. I have removed some code in order to make it easier to follow. Just one more note, I use a field/value called ParentUNID to keep track of all documents that belong to a claim. The claim number is not associated with the claim at first, so I needed some other unique identifier. I choose to use the UniversalID of the main document (“Loss Notice”) at the time it is received into the database. Even if the actual UniversalID would change, e.g. through a replication conflict, that field will never change again.
The class is farly simple. The ClaimantData object will load amount and claimant status wheninitialized. They are then available, together with the methods of the class, to the calling code.
Class ClaimantData
Public claimantdoc As NotesDocument
Public unid As String ' Store UniversalID of claimant document
Public parentunid As String
Public amounts As AmountData
Public claimcare As ClaimCareData
Public status As ClaimantStatusData
Public Parallel As Integer
Public Sub New(doc As NotesDocument)
Dim claimnumber As String
Dim claimant As Integer
Set claimantdoc = doc
unid = doc.UniversalID
parentunid = doc.GetItemValue("ParentUNID")(0)
claimnumber = doc.GetItemValue("ClaimNumber")(0)
claimant = Cint(doc.GetItemValue("Claimant_Number")(0))
If Lcase(doc.GetItemValue("TransferredToParallel")(0)) = "yes" Then
Parallel = True
Else
Parallel = False
End If
Set amounts = New Amounts(claimnumber, claimant)
Set status = New ClaimantStatusData(doc)
End Sub
Public Function GetValue(fieldname) As Variant
GetValue = claimantdoc.GetItemValue(fieldname)(0)
End Function
Public Function SetValue(fieldname, Byval value As Variant) As Variant
Call claimantdoc.ReplaceItemValue(fieldname, value)
End Function
Public Function GetVariant(fieldname) As Variant
GetVariant = claimantdoc.GetItemValue(fieldname)
End Function
Public Sub Save()
Call claimantdoc.Save(True,True)
End Sub
Public Function DisplayName() As String
If Fulltrim(GetValue("Claimant_Name")) = "" Then
DisplayName = GetValue("Claimant_Company")
Else
DisplayName = GetValue("Claimant_Name")
End If
End Function
Public Function GetXML()
Dim tempxml As String
If claimantdoc Is Nothing Then
Msgbox "Claimant document is not loaded, no data returned.",,"ClaimantData.GetXML()"
GetXML = ""
Exit Function
End If
tempxml = "<claimntno>" & claimantdoc.GetValue("Claimant_Number") & "</claimntno>" & CRLF
tempxml = tempxml + "<extclmntno>" & claimantdoc.getValue("ClaimantNumberExternal") & "</extclmntno>" & CRLF
tempxml = tempxml + "<classcode>" & claimantdoc.pClassCode(0) & "</classcode>" & CRLF
tempxml = tempxml + "<cvgcode>" & claimantdoc.Claimant_LossType(0) & "</cvgcode>" & CRLF
tempxml = tempxml + "<table>" & claimantdoc.pTable(0) & "</table>" & CRLF
If claimantdoc.Unknown(0)="Yes" Then
tempxml = tempxml + "<claimntnam>* unknown *</claimntnam>" & CRLF
Elseif claimantdoc.Claimant_Name(0)="" Then
tempxml = tempxml + "<claimntnam>" & dsClaimLink.EncodeXML(claimantdoc.Claimant_Company(0)) & "</claimntnam>" & CRLF
Else
tempxml = tempxml + "<claimntnam>" & dsClaimLink.EncodeXML(claimantdoc.Claimant_Name(0)) & "</claimntnam>" & CRLF
End If
' Check if we have amounts loaded
If Not amounts Is Nothing Then
tempxml = tempxml + "<lossamt>" & Format$(amounts.lp,"###0.00") & "</lossamt>" & CRLF
tempxml = tempxml + "<expamt>" & Format$(amounts.ep,"###0.00") & "</expamt>" & CRLF
End If
GetXML = tempxml
End Function
End Class
There is a function to get an XML representation of the claimant. This one is used when data is sent to the dsClaimLink COM object. I also have a function to return the name to display, either the person name or the company name of the former is blank. I could have implemented this using the Get/Set statements, but they have to be defined as a pair and this is a read-only property of the object.